SWFSH.com 上海Flash开发者交流会

最新新闻：
· 耐克Nike+ GPS应用无配件即可记录运动(2010-09-07 22:49)
· Google真相：决策贡献及其艰苦抉择(2010-09-07 22:46)
· 谷歌CEO宣布今秋将在美国推出电视服务(2010-09-07 22:13)
· 环球企业家：亚马逊出手(2010-09-07 21:39)
· Google 代码搜索升级，新增 Chromium 订制版(2010-09-07 21:31)

Alpha mask using Actionscript 3.0

作者: Seven_Yuan 发表于 2010-09-03 17:15 原文链接阅读: 131 评论: 0

Have you ever tried to create an alpha mask using Actionscript 3.0?
The thing is reachable with the method copyChannel of the BitmapData class.

Load an external image
Create a new instance of BitmapData (bitmap_data) and assign it to bitmapData property of the external bitmap
Create a new instance of BitmapData (bitmap_data_copy) with same size of external bitmap
Copy the pixels of external bitmap in the new instance bitmap_data_copy
Use the dispose method on bitmap_data to free memory
Create a mask form using a Shape
Create a new instance of BitmapData (bitmap_data_shape) the same size of external image and use draw method over shape
bitmap_data_copy uses the method copyChannel on bitmap_data_shape
Give bitmap_data_copy to property bitmapData of external image

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.net.*;
    import flash.geom.*;
    import flash.filters.*;

    public class Main extends MovieClip
    {
        private var loaded_bitmap:Bitmap;
        private var bitmap_data:BitmapData;
        private var bitmap_data_copy:BitmapData;
        private var bitmap_data_shape:BitmapData;

        private var shape:Shape;

        public function Main()
        {
            addEventListener(Event.ADDED_TO_STAGE,init);
            addEventListener(Event.REMOVED_FROM_STAGE,destroy);
        }

        private function init(evt:Event):void
        {
            removeEventListener(Event.ADDED_TO_STAGE,init);

            loadImage();
        }

        private function loadImage():void
        {
            var request:URLRequest=new URLRequest("tiger.jpg");
            var loader:Loader=new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE,onImageLoaded);
            loader.load(request);
        }

        private function onImageLoaded(evt:Event):void
        {
            evt.target.removeEventListener(Event.COMPLETE,onImageLoaded);

            loaded_bitmap=evt.target.loader.content as Bitmap;

            createAlphaMask();
        }

        private function createAlphaMask():void
        {
            bitmap_data=loaded_bitmap.bitmapData;
            var w:Number=bitmap_data.width;
            var h:Number=bitmap_data.height;

            bitmap_data_copy=new BitmapData(w,h,true,0x00FFFFFF);
            bitmap_data_copy.copyPixels(bitmap_data,bitmap_data.rect,new Point());
            bitmap_data.dispose();

            shape=createMask(w,h);
            bitmap_data_shape=new BitmapData(w,h,true,0x00FFFFFF);
            bitmap_data_shape.draw(shape);

            bitmap_data_copy.copyChannel(bitmap_data_shape,bitmap_data_shape.rect,new Point(),BitmapDataChannel.ALPHA,BitmapDataChannel.ALPHA);
            loaded_bitmap.bitmapData=bitmap_data_copy;
            addChild(loaded_bitmap);
        }

        private function createMask(w:Number,h:Number):Shape
        {
            var new_shape:Shape=new Shape();
            new_shape.graphics.beginFill(0xFFFFFF);
            new_shape.graphics.drawEllipse(50,50,w-100,h-100);
            new_shape.graphics.endFill();

            var blur_filter:BlurFilter=new BlurFilter(50,50,BitmapFilterQuality.HIGH);
            new_shape.filters=[blur_filter];
            addChild(new_shape);

            return new_shape;
        }

        private function destroy(evt:Event):void
        {
            removeEventListener(Event.REMOVED_FROM_STAGE,destroy);

            bitmap_data_copy.dispose();
            bitmap_data_shape.dispose();

            removeChild(loaded_bitmap);
            removeChild(shape);

            loaded_bitmap=null;
            shape=null;
        }
    }
}

评论: 0　查看评论　发表评论

Unicode and Flash Player

作者: Seven_Yuan 发表于 2010-09-03 17:15 原文链接阅读: 125 评论: 0

Flash Player 6 (and later) supports Unicode text encoding. Any user who installed Flash Player 6 or later can display text in multiple languages, regardless of the language used by the operating system running Flash Player, provided the computer
are installed the correct characters.
Flash Player assumes that all external text files associated with an application in Flash Player are encoded with Unicode, unless it is otherwise noted.
For applications in Flash Macromedia Flash Player 5 or earlier, that were created in Flash MX or earlier, Flash Player 6 (and earlier) displays the text using the traditional code of the operating system running the player.
For more information about Unicode, visit www.unicode.org.

Text encoding in Flash Player
By default, Flash Player 7 requires that all text is encoded with Unicode.
If the charging document text file or external XML files, the text of these files should be encoded in UTF-8.
Create these files using the Strings panel or a text editor or HTML, which can save files in Unicode.

Unicode encoding formats supported by Flash Player
When reading text data in Flash, Flash Player looks at the first two bytes in the file to detect a BOM (Byte Order Mark, mark byte order), a standard formatting convention used to identify the format of Unicode.
If no BOM is detected, the text encoding is interpreted as UTF-8 (an 8-bit encoding format). It is advisable to use UTF-8 in their applications.
If Flash Player detects any of the following BOM, the encoding format of the text is interpreted as follows:

If the first byte of the file is OxFE OxFF and the second is, the encoding is interpreted as UTF-16 BE (Big Endian). This encoding is used for systems
Macintosh.
If the first byte of the file is OxFF OxFE and the second is, the encoding is interpreted as UTF-16 LE (Little Endian). This encoding is used for systems
Windows.

Most text editors can save files in UTF-16 BE or LE automatically add the BOMs to the files.
Note: if you set the property system.useCodepagesu true, the text is interpreted using the traditional code of the operating system on which Flash Player is running, is not interpreted as Unicode.

Encoding in external XML files
You can not change the encoding of an XML file by changing the encoding tag.
The Flash Player identifies the encoding of an external XML file using the same rules used for all external files.
If not detected any BOM at the beginning of the file, it is assumed that the file is encoded in UTF-8.
If a BOM is found, the file is interpreted as encoded in UTF-16 BE or LE.

评论: 0　查看评论　发表评论

Stop all sounds with Actionscript 3.0

作者: Seven_Yuan 发表于 2010-09-03 17:14 原文链接阅读: 127 评论: 0

import flash.media.SoundMixer;
SoundMixer.stopAll();

评论: 0　查看评论　发表评论